Bottom, Left
Расположение сцены в холсте
Блокноты MuPAD® будут демонтированы в будущем релизе. Используйте live скрипты MATLAB® вместо этого.
Live скрипты MATLAB поддерживают большую часть функциональности MuPAD, хотя существуют некоторые различия. Для получения дополнительной информации смотрите, Преобразовывают Notebook MuPAD в Live скрипты MATLAB.
Сводные данные значения
Bottom, Left | Дополнительный | Смотрите ниже |
Графические примитивы
| Объекты | Значения по умолчанию |
|---|---|
plot::Scene2d, plot::Scene3d |
|
Описание
С набором Layout атрибута холста к Absolute или Relative, сцены в холсте могут масштабироваться и располагаться свободно.
Bottom = b размещает нижнюю сторону сцены на расстоянии b выше нижней стороны холста.
Left = l помещает левую сторону сцены на расстоянии l справа от левой стороны холста.
Автоматические схемы Layout размещения = Horizontal, Layout = Vertical и Layout = Tabular доступен для холста, который содержит несколько сцен.
Настройки Layout холста = Absolute и Layout = Relative выключает автоматический режим размещения и позволяет располагать каждую сцену свободно через атрибуты Bottom и Left, соответственно. Эти атрибуты устанавливают расстояния левого нижнего угла сцены к нижней части, соответственно левая сторона холста. Эти значения могут быть установлены отдельно для каждой сцены.
Следующие изображения иллюстрируют, что расположение сцен в холсте через сцену приписывает Bottom и Left:
С Layout = Absolute, расстояние левого нижнего угла сцены к левому нижнему углу холста должно быть задано через физические длины с модулем, например, Bottom = 2*unit::mm, Left = 0.1*unit::inch. Недостающие модули приняты, чтобы быть мм.
С Layout = Relative, расстояние нижней стороны сцены нижней стороне холста должно быть задано как часть высоты холста, т.е. как номер между 0 и 1. Расстояние левой стороны сцены к левой стороне холста должно быть задано как часть ширины холста, т.е. как номер между 0 и 1.
Левый нижний угол сцены может быть помещен вне холста. Части сцены вне холста отсекаются.
Могут быть созданы перекрывающиеся сцены. В такой ситуации может быть полезно создать прозрачные сцены (без фона) через BackgroundTransparent = TRUE.
Примеры
Пример 1
Мы демонстрируем размещение холста с Layout = Absolute. Сцена S1 расположена автоматически в холсте с помощью значений по умолчанию Bottom = 0, Left = 0. Меньшие сцены S2 и S3 расположены явным образом через Bottom и Left:
S1 := plot::Scene3d(plot::Sphere(1, [0, 0, 0],
Color = RGB::Red),
Width = 70*unit::mm, Height = 70*unit::mm,
BackgroundColor = RGB::Grey):
S2 := plot::Scene3d(plot::Box(-1..1, -1..1, -1..1,
Color = RGB::Green),
Width = 30*unit::mm, Height = 30*unit::mm,
Left = 60*unit::mm, Bottom = 3*unit::mm):
S3 := plot::Scene3d(plot::Cone(1, [0, 0, 0], [0, 0, 1],
Color = RGB::Blue),
Width = 30*unit::mm, Height = 30*unit::mm,
Left = 60*unit::mm, Bottom = 36*unit::mm):
plot(S1, S2, S3, Layout = Absolute,
plot::Canvas::BorderWidth = 1.0*unit::mm,
plot::Canvas::BorderColor = RGB::Black,
plot::Canvas::Width = 92*unit::mm,
plot::Canvas::Height = 72*unit::mm,
plot::Scene3d::BorderWidth = 0.5*unit::mm,
plot::Scene3d::BorderColor = RGB::Black):
Мы делаем фон небольших сцен прозрачным и выключаем оси:
S2::BackgroundTransparent := TRUE:
S2::Axes := None:
S3::BackgroundTransparent := TRUE:
S3::Axes := None:
plot(S1, S2, S3, Layout = Absolute,
plot::Canvas::BorderWidth = 1.0*unit::mm,
plot::Canvas::BorderColor = RGB::Black,
plot::Canvas::Width = 92*unit::mm,
plot::Canvas::Height = 72*unit::mm,
plot::Scene3d::BorderWidth = 0.5*unit::mm,
plot::Scene3d::BorderColor = RGB::Black):
delete S1, S2, S3:
Пример 2
Мы демонстрируем размещение холста с Layout = Relative. Кроме заголовков сцены и расположения через Bottom и Left, все атрибуты сцены установлены в вызове plot через спецификации, такие как plot::Scene2d::Width и т.д. Это отличает атрибуты сцены от атрибутов холста Width, BorderWidth и т.д.
S1 := plot::Scene2d(plot::Function2d(sin(x), x = 0..2*PI),
Left = 0.02, Bottom = 0.46,
Header = "the sine function"):
S2 := plot::Scene2d(plot::Function2d(cos(x), x = 0..2*PI),
Left = 0.51, Bottom = 0.46,
Header = "the cosine function"):
S3 := plot::Scene2d(plot::Function2d(tan(x), x = 0..PI),
Left = 0.02, Bottom = 0.02,
Header = "the tan function"):
S4 := plot::Scene2d(plot::Function2d(cot(x), x = 0..PI),
Left = 0.51, Bottom = 0.02,
Header = "the cot function"):
plot(S1, S2, S3, S4, Layout = Relative,
Width = 120*unit::mm, Height = 80*unit::mm,
BorderWidth = 0.5*unit::mm,
HeaderFont = ["Times New Roman", 18, Bold],
Header = "trigonometric functions",
plot::Scene2d::Width = 0.475,
plot::Scene2d::Height = 0.42,
plot::Scene2d::BorderWidth = 0.2*unit::mm,
plot::Scene2d::HeaderFont =
["Times New Roman", Italic, 12]):
delete S1, S2, S3, S4: