Несколько классов в Visual Basic компоненте

Чтобы создать компонент для этого примера, смотрите первые несколько шагов нескольких классов в компоненте .NET. Затем создайте Microsoft^® Визуальный базовый^® применение следующим образом:

Рассмотрим пример приложения для этого примера в matlabroot\ toolbox\dotnetbuilder\Примеры\VS Version\ NET\SpectraExample\SpectraVBApp\SpectraApp.vb.

Список программ показан здесь.

SpectraApp.vb

Imports System

Imports MathWorks.MATLAB.NET.Utility
Imports MathWorks.MATLAB.NET.Arrays

Imports SpectraComp


Namespace MathWorks.Examples.SpectraApp

    ' <summary>
    ' This application computes and plots the power spectral density of an input signal. 
    ' </summary>
    Class SpectraDemoApp

#Region " MAIN "

        ' <summary>
        ' The main entry point for the application.
        ' </summary>
        Shared Sub Main(ByVal args() As String)
            Try
                Const interval As Double = 0.01   ' The sampling interval
                Const numSamples As Integer = 1001   ' The number of samples

                ' Construct input data as sin(2*PI*15*t) + (sin(2*PI*40*t) plus a
                ' random signal.  Duration= 10; Sampling interval= 0.01
                Dim data As MWNumericArray = New MWNumericArray(MWArrayComplexity.Real, 
                                             MWNumericType.Double, numSamples)

                Dim random As Random = New Random

                ' Initialize data 
                Dim t As Double
                Dim idx As Integer
                For idx = 1 To numSamples
                    t = (idx - 1) * interval
                    data(idx) = New MWNumericArray(Math.Sin(2.0 * Math.PI * 15.0 * t) + 
                                    Math.Sin(2.0 * Math.PI * 40.0 * t) + 
                                    random.NextDouble())
                Next idx

                ' Create a new signal analyzer object
                Dim signalAnalyzer As SignalAnalyzer = New SignalAnalyzer

                ' Compute the fft and power spectral density for the data array
                Dim argsOut() As MWArray = signalAnalyzer.computefft(3, data, 
                                                 MWArray.op_Implicit(interval))

                ' Print the first twenty elements of each result array
                Dim numElements As Integer = 20
                Dim resultArray As MWNumericArray = 
                         New MWNumericArray(MWArrayComplexity.Complex, 
                                    MWNumericType.Double, numElements)

                For idx = 1 To numElements
                    resultArray(idx) = (CType(argsOut(0), MWNumericArray))(idx)
                Next idx

                Console.WriteLine("FFT:{0}{1}{2}", Chr(10), resultArray, Chr(10))

                For idx = 1 To numElements
                    resultArray(idx) = (CType(argsOut(1), MWNumericArray))(idx)
                Next idx

                Console.WriteLine("Frequency:{0}{1}{2}", Chr(10), resultArray, Chr(10))

                For idx = 1 To numElements
                    resultArray(idx) = (CType(argsOut(2), MWNumericArray))(idx)
                Next idx

                Console.WriteLine("Power Spectral Density:{0}{1}{2}", 
                  Chr(10), resultArray, Chr(10))

                ' Create a new plotter object
                Dim plotter As Plotter = New Plotter

                ' Plot the fft and power spectral density for the data array
                plotter.plotfft(argsOut(0), argsOut(1), argsOut(2))

                Console.ReadLine()  ' Wait for user to exit application

            Catch exception As Exception
                Console.WriteLine("Error: {0}", exception)

            End Try
        End Sub
#End Region

    End Class
End Namespace

Программа делает следующее:

Создает вход массива со значениями, представляющими случайный сигнал с двумя синусоидами на 15 и 40 Гц, встроенными в него
Использует MWNumericArray для обработки преобразования данных
Примечание
Для получения информации об этих классах преобразования данных смотрите MATLAB MWArray Class Ссылка, доступный в matlabroot\ help\dotnetbuilder\MWArrayAPI папка, где matlabroot представляет ваш MATLAB^® папка установки
Создание экземпляров SignalAnalyzer объект
Вызывает computefft метод, который вычисляет БПФ, частоту и спектральную плотность
Создание экземпляров Plotter объект
Вызывает plotfft метод, который строит графики данных
Использует try/ catch блок, для обработки исключений

Следующие операторы

Dim data As MWNumericArray = New MWNumericArray_
    (MWArrayComplexity.Real, MWNumericType.Double, numSamples)
...
Dim resultArray As MWNumericArray = New MWNumericArray_
    (MWArrayComplexity.Complex, 
     MWNumericType.Double, numElements)

показать, как использовать MWArray Класс библиотеку, чтобы создать необходимые типы данных.

Следующий оператор

Dim signalAnalyzer As SignalAnalyzer = New SignalAnalyzer

создает образец класса SignalAnalyzer, и следующий оператор

Dim argsOut() As MWArray = 
    signalAnalyzer.computefft(3, data, 
        MWArray.op_Implicit(interval))

вызывает метод computefft и запросить три выходов.

Создайте SpectraApp приложение с использованием Visual Studio^® .NET.
1. The SpectraVBApp папка содержит файл проекта Visual Studio .NET для этого примера. Откройте проект в Visual Studio .NET двойным кликом мыши SpectraVBApp.vbproj в Windows^® Исследователь. Вы также можете открыть его с рабочего стола, щелкнув правой кнопкой мыши SpectraVBApp.vbproj > Open Outside MATLAB.
2. Добавьте ссылку на MWArray компонент, который matlabroot\ toolbox\dotnetbuilder\bin\ architecture\framework_version\mwarray.dll.
3. При необходимости добавьте (или обновите местоположение) ссылку на SpectraComp компонент, созданный на предыдущем шаге. (Компонент, SpectraComp.dll, находится в \SpectraExample\SpectraComp\x86\V2.0\Debug\distrib подпапка рабочей области.)
Создайте и запустите приложение в Visual Studio .NET.

Документация

Несколько классов в Visual Basic компоненте

Документация MATLAB Compiler SDK

Поддержка