Откройте N-канал MOSFET (основанная на интерполяционной таблице) модель

Откройте подсхему MOSFET

Подсхема содержит модель SPICE мощного транзистора N-канала. Чтобы открыться это, в окне команды MATLAB, вводит редактирование IAUC100N04S6L014.cir.

Создайте список соединений характеристик передачи

Можно создать список соединений SPICE, который указывает целевой рабочий диапазон для подсхемы. Список соединений IAUC100N04S6L014_idvgs.net симулирует характеристики передачи со списком напряжений источника дренажа.

* Transfer characteristic of MOSFET IAUC100N04S6L014
.opt DampInductors=0 Thev_Induc=1 Gfarad=0 Gfloat=0 reltol=1e-05 abstol=1e-05 vntol= 1e-05 Gmin=0 cshunt=0 cshuntintern=0 gshunt=0 topologycheck=0

X1 dut1 dut2 dut3 dut4 dut5 IAUC100N04S6L014
V1 dut1 0 2
V2 dut2 0 pwl(0 0 20 4.5)
V3 dut3 0 0
V5 dut5 0 27
.step V1 list 2 5 8 11 14
.tran 1m 20
.lib IAUC100N04S6L014.cir
.end

Установите параметры интерполяционной таблицы для характеристик передачи

Чтобы получить необходимые характеристики передачи MOSFET, запустите симуляцию в SPICE. ee_mosfet_tabulated_setparam скрипт использует результаты симуляции, сохраненные в IAUC100N04S6L014_idvgs1.raw необработанные файлы, чтобы установить значения параметров для (Основанного на интерполяционной таблице) N-Channel MOSFET. Чтобы установить параметры канала MOSFET, во вкладке Define Condition, проверяют Set MOSFET channel parameters поле или вызов set_param функция.

Сравните характеристики передачи

График ниже сравнивает характеристики передачи N-Channel MOSFET (основанного на интерполяционной таблице) с результатами симуляции подсхемы SPICE.

Создайте список соединений выходных характеристик

Чтобы параметрировать (основанный на интерполяционной таблице) N-Channel MOSFET, можно также использовать выходные характеристики данные SPICE. Список соединений IAUC100N04S6L014_idvds.net симулирует выходные характеристики со списком напряжений источника логического элемента.

* Output characteristic of MOSFET IAUC100N04S6L014
.opt DampInductors=0 Thev_Induc=1 Gfarad=0 Gfloat=0 reltol=1e-05 abstol=1e-05 vntol= 1e-05 Gmin=0 cshunt=0 cshuntintern=0 gshunt=0 topologycheck=0

X1 dut1 dut2 dut3 dut4 dut5 IAUC100N04S6L014
V1 dut1 0 pwl(0 0 20 15)
V2 dut2 0 2
V3 dut3 0 0
V5 dut5 0 27
.step V2 1 4 0.5
.tran 2m 20
.lib IAUC100N04S6L014.cir
.end

Установите параметры интерполяционной таблицы для выходных характеристик

IAUC100N04S6L014_idvds1.raw необработанные хранилища файлов выходные характеристики симулированы в SPICE. Чтобы изменить необработанный путь к файлу и тип графика, задайте соответствующие параметры во вкладке Define Condition или вызовите set_param функция.

Сравните выходные характеристики

График ниже сравнивает выходные характеристики N-Channel MOSFET (основанного на интерполяционной таблице) с результатами симуляции подсхемы SPICE.

Создайте емкость по сравнению со списком соединений напряжения источника дренажа

Чтобы параметрировать сведенную в таблицу емкость N-Channel MOSFET, создайте список соединений SPICE, который симулирует входную емкость (Ciss), противоположная емкость передачи (Crss) и выходная емкость по сравнению с напряжением источника дренажа с определенным напряжением источника логического элемента. Список соединений IAUC100N04S6L014_cvds.net симулирует результаты I-V Ciss и Crss маленьким сигналом AC на напряжении источника логического элемента и результаты I-V Coss маленьким сигналом AC на напряжении источника дренажа.

* Ciss Crss Coss measurement of MOSFET IAUC100N04S6L014
.opt DampInductors=0 Thev_Induc=1 Gfarad=0 Gfloat=0 reltol= 1e-05 abstol= 1e-05 vntol= 1e-05 Gmin=0 cshunt=0 cshuntintern=0 gshunt=0 topologycheck=0

* Ciss Crss I-V with Vgs small AC
X1 dut11 dut12 dut13 dut14 dut15 iauc100n04s6l014
V11 dut11 0 sine({VDC} 0 1e6)
V12 dut12 0 sine(0 0.05 1e6)
V13 dut13 0 0
V15 dut15 0 27

* Coss I-V with Vds small AC
X2 dut21 dut22 dut23 dut24 dut25 iauc100n04s6l014
V21 dut21 0 sine({VDC} 0.05 1e6)
V22 dut22 0 sine(0 0 1e6)
V23 dut23 0 0
V25 dut25 0 27
*.param VDC = 0
.step param VDC 0 30 1
.tran 1e-7 5e-6 0 2e-8
.inc IAUC100N04S6L014.cir
.end

Установите параметры интерполяционной таблицы для емкости

IAUC100N04S6L014_cvds1.raw необработанные хранилища файлов емкость результаты I-V симулированы в SPICE. Устанавливать параметры емкости MOSFET, в Define Conditions перейдите, проверяйте Set MOSFET capacitance parameters поле или вызов set_param функция.

Сравните Ciss, Crss и Coss Capacitance

График ниже сравнивает Ciss, Crss и емкость Coss N-Channel MOSFET с результатами симуляции подсхемы SPICE.

Создайте исходный дренаж прямой диодный список соединений характеристик

Чтобы параметрировать сведенный в таблицу прямой диод N-Channel MOSFET, создайте список соединений SPICE с MOSFET, действующим в от области и с противоположным напряжением источника дренажа смещения. Список соединений IAUC100N04S6L014_diode.net симулирует текущие характеристики напряжения прямого диода.

* Source-Drain Forward Diode of MOSFET IAUC100N04S6L014
.opt DampInductors=0 Thev_Induc=1 Gfarad=0 Gfloat=0 reltol=1e-05 abstol=1e-05 vntol= 1e-05 Gmin=0 cshunt=0 cshuntintern=0 gshunt=0 topologycheck=0

X1 dut1 dut2 dut3 dut4 dut5 IAUC100N04S6L014
V1 dut1 0 pwl(0 0 20 -5)
V2 dut2 0 -10
V3 dut3 0 0
V5 dut5 0 27
.tran 0.1 20
.lib IAUC100N04S6L014.cir
.end

Установите параметры интерполяционной таблицы для исходного дренажа прямой диод

IAUC100N04S6L014_diode1.raw необработанные хранилища файлов foward диодные характеристики симулированы в SPICE. Устанавливать диодные параметры MOSFET, в Define Conditions перейдите, проверяйте Set MOSFET diode parameters поле или вызов set_param функция

Сравните прямые диодные характеристики

График ниже сравнивает прямые диодные характеристики N-Channel MOSFET с результатами симуляции подсхемы SPICE.