Пример 1

Создайте новый файл во временной папке системы. Имя временной папки отличается для других платформ. Команда fopen с опцией TempFile создает файл во временной папке любой системы (если такая папка существует):

fid := fopen(TempFile, Write, Text): 
fprint(Unquoted, fid, "a := 3; b := 5; a + b;"):

Используйте fname, чтобы возвратить имя временного файла, который вы создали. Используйте fclose, чтобы закрыть файл:

file := fname(fid):
fclose(fid)

При чтении файла MuPAD выполняет операторы. Каждый производит печать вывод. Второй 8 ниже является возвращаемым значением fread:

delete a, b:
fread(file);

Теперь, переменным a и b присвоили значения в файле:

a, b

С опцией Quiet только распечатано возвращаемое значение fread:

delete a, b:
fread(file, Quiet)

delete a, b:

Пример 2

Следующий пример демонстрирует опцию Plain. Во-первых, соответствующий входной файл создается:

fid := fopen(TempFile, Write, Text): 
fprint(Unquoted, fid,
       "f := proc(x) begin x^2 end_proc:",
       "a := f(3): b := f(4):"):
file := fname(fid):
fclose(fid)

Задайте alias для f:

alias(f = "some text"):

Ошибка происходит, при попытке считать файл без опции Plain. В контексте синтаксического анализатора сеанса MuPAD псевдоним заменяет f соответствующей строкой в присвоении f := .... Однако строки не могут быть присвоены значение:

fread(file)

Error: Invalid left-hand side. [_assign]
  Reading File: /tmp/mupad.351omQ

С опцией Plain не возникает никакая такая ошибка: псевдоним для f проигнорирован fread:

fread(file, Plain):
a, b

unalias(f):
delete f, a, b:

Пример 3

Вы используете write, чтобы сохранить значение идентификатора a во временном файле:

a := PI + 1:
fid := fopen(TempFile, Write, Text): 
file := fname(fid):
write(file, a):
delete a:

Этот файл открыт для чтения с fopen:

n := fopen(file):

Дескриптор файла, возвращенный fopen, может быть передан fread. Чтение файла восстанавливает значение a:

fread(n):
a

fclose(n):
delete a:

Пример 4

Чтобы задать кодирование для чтения данных, используйте Encoding. Опция Encoding применяется только к текстовым файлам, которые открыты с помощью имени файла и не дескриптора файла. Откройте временный файл и напишите оператор str := "abcäöü" в кодировании "UTF-8":

fprint(Unquoted, Text, Encoding="UTF-8",
                       "fread_test",
                       "str := \"abcäöü\"")

Задайте кодирование, чтобы считать файл. fread выполняет оператор:

fread("fread_test", Encoding="UTF-8"):

Если вы не задаете кодирование, системное кодирование по умолчанию используется. Таким образом ваш вывод может отличаться от показанного затем. Символы, нераспознанные системным кодированием по умолчанию, заменяются символом замены по умолчанию для того кодирования:

fread("fread_test"):

Возвращаемые значения

Возвращаемое значение последнего оператора файла.