Пример 1

Каждый объект имеет слот "dom":

x::dom = domtype(x),
slot(45, "dom") = domtype(45),
sin::dom = domtype(sin)

Пример 2

Здесь мы получаем доступ к существующему слоту "float" функциональной среды sin, реализующий синусоидальную функцию. Слот плавающий является снова функциональной средой и может быть назван как любая функция MuPAD. Отметьте, однако, различную функциональность: в отличие от sin, слот плавающий всегда пытается вычислить приближение с плавающей точкой:

s := sin::float:  s(1), sin(1)

Со следующими командами s становится функциональной средой sin кроме измененного слота "float". Вызов slot не имеет никакого эффекта на исходную функцию sin, потому что slot возвращает копию функциональной среды:

s := funcenv(sin):
s::float := x -> float(x - x^3/3!):
s(PI/3) = sin(PI/3), s::float(1) <> sin::float(1)

delete s:

Пример 3

Если вы используете функцию slot, чтобы изменить записи слота в области, необходимо иметь в виду, что вы изменяете область:

old_one := Dom::Float::one

newDomFloat := slot(Dom::Float, "one", 1):
newDomFloat::one, Dom::Float::one

Мы восстанавливаем исходное состояние:

slot(Dom::Float, "one", old_one):  Dom::Float::one

delete old_one, newDomFloat:

Пример 4

Функциональная среда sin не содержит слот "sign". Так доступ к этому слоту приводит к FAIL:

slot(sin, "sign"), sin::sign

Пример 5

Мы задаем функциональную среду для функции, вычисляя логарифм к основному 3:

log3 := funcenv(x -> log(3, x)):

Если функциональный info должен дать некоторую информацию о log3, мы должны задать слот "info" для этой функции:

log3::info := "log3 -- the logarithm to the base 3":

info(log3)

log3 -- the logarithm to the base 3

Оператор delete используется для удаления слота:

delete log3::info: info(log3)

log3(x) -- a library procedure [try ?log3 for help]

Не возможно удалить специальный слот "dom":

delete log3::dom

Error: Invalid argument. [delete]

delete log3:

Пример 6

Здесь мы демонстрируем тонкое различие между функцией slot и использованием :: - оператор в присвоениях. Следующий вызов добавляет слот "xyz" в доменный DOM_INT целых чисел:

delete b: d := b: b := DOM_INT: slot(d, "xyz", 42):

Слот "xyz" DOM_INT изменяется, потому что d полностью оценен с результатом DOM_INT. Следовательно, слот DOM_INT::xyz установлен в 42:

slot(d, "xyz"), slot(DOM_INT, "xyz")

Вот результат при использовании :: - оператор: d только оценен с уровнем 1, т.е. это оценено к идентификатору b. Однако нет никакого слота b::xyz, и ошибка происходит:

delete b: d := b: b := DOM_INT: d::xyz := 42

Error: Unknown slot 'd::xyz'. [slot]

delete b, d:

Пример 7

Первый аргумент slot не сглажен. Это предоставляет доступ к слотам последовательностей выражения и объектов null():

slot((a, b), "dom") = (a,b)::dom,
slot(null(), "dom") = (null())::dom

Пример 8

Мы даем пример для использования функционального make_slot. Элемент undefined доменного stdlib::Undefined представляет неопределенное значение. Любой функциональный f должен привести к f(undefined) = undefined. В реализации stdlib::Undefined мы находим:

undef := newDomain("stdlib::Undefined"):
undefined := new(undef):
undef::func_call := proc() begin undefined end_proc;
undef::make_slot := undef::func_call:

Следующий механизм происходит автоматически для функционального f, который является сверхзагружаемым его первым аргументом: в вызове f(undefined) это проверяется, существует ли слот undef::f. Если дело обстоит не так, функция make_slot создает этот слот “на лету”, производя значение undefined. Таким образом, через перегрузку, f(undefined) возвращает значение undefined.

Пример 9

Следующий пример скорее совершенствуется и технический. Это демонстрирует перегрузку функции slot, чтобы реализовать доступ к слоту и назначения слотов для других объектов, чем области (DOM_DOMAIN) или функциональные среды (DOM_FUNC_ENV). Следующий пример задает слоты "numer" и "denom" для рациональных чисел. Доменный DOM_RAT таких чисел не имеет слотов "numer" и "denom":

domtype(3/4)

slot(3/4, "numer")

Error: Unknown slot '(3/4)::numer'. [slot]

Мы можем изменить DOM_RAT, как бы то ни было. Для этого мы имеем к оставить без защитыDOM_RAT временно:

unprotect(DOM_RAT):
DOM_RAT::slot :=
  proc(r : DOM_RAT, n : DOM_STRING, v=null(): DOM_INT)
      local i : DOM_INT;
  begin
      i := contains(["numer", "denom"], n);
      if i = 0 then
         error("Unknown slot \"".expr2text(r)."::".n."\"")
      end;
      if args(0) = 3 then
         subsop(r, i = v)
      else
         op(r, i)
      end
  end_proc:

Теперь, мы можем получить доступ к операндам рациональных чисел, которые являются числителем и знаменателем соответственно через наши новые слоты:

slot(3/4, "numer"), (3/4)::numer,
slot(3/4, "denom"), (3/4)::denom

a := 3/4:  slot(a, "numer", 7)

a::numer := 11:  a

Мы восстанавливаем исходное поведение:

delete DOM_RAT::slot, a: protect(DOM_RAT, Error):

Возвращаемые значения

slot(d, "n") возвращает значение слота; slot(d, "n", v) возвращает объект d с добавленным или измененным слотом; slot(object, "dom") возвращает доменный тип объекта.

Перегруженный

d