Пример 1

map работает на выражения:

map(a + b + 3, sin)

Дополнительные аргументы map передаются сопоставляемой функции:

map(a + b + 3, f, x, y)

В следующем примере мы добавляем 10 к каждому элементу списка:

map([1, x, 2, y, 3, z], _plus, 10)

Пример 2

Как большинство других функций MuPAD^®, map не изменяет его первый аргумент, но возвращает модифицированную копию:

a := [0, PI/2, PI, 3*PI/2]:
map(a, sin)

Список a все еще имеет его исходное значение:

a

Пример 3

map не анализирует рациональные и комплексные числа:

map(3/4, _plus, 1), map(3 + 4*I, _plus, 1)

map не анализирует строки:

map("MuPAD", text2expr)

map не анализирует полиномы:

map(poly(x^2 + x + 1), _plus, 1)

Используйте mapcoeffs применять функцию ко всем коэффициентам полинома:

mapcoeffs(poly(x^2 + x + 1), _plus, 1)

Пример 4

Первый аргумент не сглажен:

map((1, 2, 3), _plus, 2)

Пример 5

Иногда функция MuPAD возвращает набор или список больших символьных выражений, содержащих математические константы и т.д. Чтобы получить лучшую интуицию о результате, можно сопоставить функциональный float ко всем элементам, который часто решительно уменьшает размер выражений:

solve(x^4 + x^2 + PI, x)

map(%, float)

Пример 6

В следующем примере мы удаляем значения всех глобальных идентификаторов на текущем сеансе MuPAD. Команда anames(All, User) возвращает набор с именами всех пользовательских глобальных идентификаторов, имеющих значение. Отображение функционального _delete к этому набору удаляет значения всех этих идентификаторов. Начиная с возвращаемого значения _delete пустая последовательность null(), результатом вызова является пустое множество:

x := 3: y := 5: x + y

map(anames(All, User), _delete)

x + y

Пример 7

Возможно выполнить произвольные действия со всеми элементами структуры данных через один map вызвать. Это работает путем передачи анонимной процедуры в качестве второго аргумента f. В следующем примере мы проверяем, что факт “целочисленный n ≥ 2 является главным, если и только если φ (n) = n - 1”, где φ обозначает функцию тотиента Эйлера, содержит для всего целого числа 2 ≤ n <10. Мы делаем это путем сравнения результата isprime(n) со значением истинности уравнения φ (n) = n - 1 для всех элементов n из списка, содержащего целые числа между 2 и 9:

map([2, 3, 4, 5, 6, 7, 8, 9],
    n -> bool(isprime(n) = bool(numlib::phi(n) = n - 1)))

Пример 8

Результат map не оценен далее. При желании необходимо запросить оценку явным образом eval:

map(sin(5), float);
eval(%)

delete a:
A := array(1..1, [a]);
a := 0:
map(A, sin);
map(A, eval@sin);
delete a:

Тем не менее, определенные внутренние упрощения происходят, такие как вычисление арифметических операций с числовыми аргументами. Следующий вызов заменяет sqrt(2) и PI приближениями с плавающей точкой и системой автоматически упрощает получившуюся сумму:

map(sin(5) + cos(5), float)

Этого внутреннего упрощения можно избежать путем предоставления опции Unsimplified:

map(sin(5) + cos(5), float, Unsimplified)

Пример 9

map примененный таблица изменяет только правые стороны (записи) каждого операнда таблицы. Примите, что записи обозначают цены нетто, и налог с продаж (16 процентов в этом случае) должен быть добавлен:

T := table(1 = 65, 2 = 28, 3 = 42):
map(T, _mult, 1.16)

Пример 10

map может быть перегружен для элементов областей библиотеки, если slot"map" задан. В этом примере d область, ее элементы содержит два целых числа: индекс и запись (как таблица). Для хорошего входа и элементов печати этой области slots"new" и "print" заданы:

d := newDomain("d"):
d::new := () -> new(d, args()):
d::print := object -> _equal(extop(object)):
d(1, 65), d(2, 28), d(3, 42)

Без паза "map" функциональный f будет применен к самому доменному элементу. Поскольку доменный d не имеет никакого паза "_mult", результатом является символьный _mult вызов:

map(d(1, 65), _mult, 1.16),
type(map(d(1, 65), _mult, 1.16))

Паз "map" из этой области должен сопоставить заданную функцию только на второй операнд доменного элемента. Доменный d получает паз "map" и map работает правильно (в смысле авторов) с элементами этой области:

d::map := proc(obj, f)
          begin
            if args(0) > 2 then
              d(extop(obj, 1), f(extop(obj, 2), args(3..args(0))))
            else
              d(extop(obj, 1), f(extop(obj, 2)))
            end_if
          end_proc:
map(d(1, 65), _mult, 1.16),
map(d(2, 28), _mult, 1.16),
map(d(3, 42), _mult, 1.16)

Пример 11

map не работает рекурсивно. Предположим, что мы хотим к de-вложенному-множеству вложенный список. Мы используем map применять функциональный op, который заменяет список последовательностью его операндов ко всем записям списка l. Однако это только влияет на записи на первом уровне:

l := [1, [2, [3]], [4, [5]]]:
map(l, op)

Используйте misc::maprec достигнуть желаемого поведения:

[misc::maprec(l, {DOM_LIST} = op)]

Возвращаемые значения

Копия object с f примененный все операнды.

Перегруженный

object