Атрибуты

Пример 1

Чтобы построить гистограмму нормально распределенного процесса, мы сначала создаем генератор случайных чисел с этим распределением:

X := stats::normalRandom(0, 1)

Затем, мы создаем небольшое количество “измерений”:

data := [X() $ i = 1..20]

Эти данные готовы быть помещенными в plot::Histogram2d:

plot(plot::Histogram2d(data))

Этот график, если ничто иное, показывает, что 20 выборок - очень немногие. Давайте повторим процесс с большим количеством данных:

data := [X() $ i = 1..300]:
plot(plot::Histogram2d(data))

С другой стороны, этот объем данных, конечно, выравнивает по ширине более прекрасную классификацию:

plot(plot::Histogram2d(data, Cells = [15]))

Пример 2

Также возможно дать ячейки (классы) непосредственно. Для этого необходимо дать им как области значений или списки с двумя элементами, как в следующем примере:

X := stats::normalRandom(0, 1):
data := [X() $ i = 1 .. 100]:
min(data), max(data)

h := plot::Histogram2d(data,
            Cells = [-2.5..-1.5, -1.5..-1, -1..0,
                     0..1, 1..1.5, 1.5..2.5])

plot(h)

Даже возможно использовать - infinity и infinity как значения границы в ячейках:

h::Cells := [-infinity..-2, -2..-1, -1..0,
             0..1, 1..2, 2..infinity]:
plot(h)

Пример 3

Одна потенциальная проблема с классами неравной ширины - то, что все еще высота панелей соответствует количеству точек данных в классе. Чтобы видеть, почему это может быть проблемой, считайте данные совершенно равномерно распределенными:

data := [i/1000 $ i = 1..1000]:

Строя гистограмму этих данных, мы видим только очень маленькие отклонения от прямоугольника, вызванного тем, которые 1000 и 7 являются взаимно-простыми:

plot(plot::Histogram2d(data))

Однако строя гистограмму с неровными классами, изображение выглядит очень отличающимся:

plot(plot::Histogram2d(data,
       Cells = [0..1/2, 1/2..2/3, 2/3..3/4, 3/4..4/5, 4/5..1]))

Чтобы сделать не, высота, а скорее область панели зависят от количества выборок в классе, устанавливают Area на положительное значение:

plot(plot::Histogram2d(data,
       Cells = [0..1/2, 1/2..2/3, 2/3..3/4, 3/4..4/5, 4/5..1],
       Area = 1))

Обратите внимание на то, что с Area = 1, график гистограммы масштабируется соответственно к функции плотности вероятности отображенной переменной:

X := stats::normalRandom(0, 1):
data := [X() $ i = 1..1000]:
h := plot::Histogram2d(data, Cells = [15],
                       Area = 1, Color = RGB::Blue):
f := plot::Function2d(stats::normalPDF(0, 1),
                      x = -3..3, LineWidth = 1*unit::mm,
                      Color = RGB::Black):
plot(h, f)

delete X, data, h, f: