Атрибуты

Пример 1

Мы генерируем график плотности:

p := plot::Density(cos(x^2 + y^2), x = -3..3, y = -2..2, 
                   Mesh = [60, 40]):

Объект графика представляется:

plot(p, Axes = Frame):

Это превращается в черно-белую графику, когда подходящие цвета заданы:

plot(plot::Scene2d(p, FillColor = RGB::White, 
                      FillColor2 = RGB::Black),
     plot::Scene2d(p, FillColor = RGB::Black, 
                      FillColor2 = RGB::White),
     Width = 120*unit::mm, Height = 45*unit::mm,
     Layout = Horizontal, Axes = Frame):

delete p:

Пример 2

Мы демонстрируем использование пользовательской функции управления цветом:

mycolor := proc(x, y, f)
begin
   if   f >=  2/3 then RGB::Red
   elif f >=  1/3 then RGB::Orange;
   elif f >=   0  then RGB::Yellow;
   elif f >= -1/3 then RGB::BlueLight;
   elif f >= -2/3 then RGB::Blue;
   else RGB::SlateBlueDark;
   end_if;
end_proc:
plot(plot::Density(cos(x^2 + y^2), x = -3..3, y = -2..2, 
                   Mesh = [60, 40], 
                   FillColorFunction = mycolor),
     Axes = Frame):

delete mycolor:

Пример 3

В этом примере мы демонстрируем как plot::Density может использоваться, чтобы отобразить серые данные на графике из внешнего источника. Примите, существует внешний текстовый файл PortableGrayMap Norton.pgm содержа данные такой как

P2
240 180
255
249 237 228 231 245 218 229 195 ...
      

Остающиеся данные состоят из целых чисел между 0 (черными цветами) и 255 (белыми) цветами, каждый представляющий уровень яркости пикселя (строка строкой).

Мы импортируем текстовые данные через import::readdata:

graydata := import::readdata("Norton.pgm", NonNested):

Это - длинный список всех элементов данных в файле. Мы извлекаем эти 4 элемента в первых трех линиях:

[magicvalue, xmesh, ymesh, maxgray] := graydata[1..4]

Мы удаляем заголовок из пиксельных данных. (Если существуют комментарии в файле PGM, они должны быть удалены, также).

for i from 1 to 4 do
  delete graydata[1];
end_for:

Мы преобразовываем простой список данных к вложенному списку, содержащему серые данные строк как подсписки. (Вызов level не действительно необходимо, но это значительно ускоряет преобразование на интерактивном уровне.)

L := level([graydata[(i - 1)*xmesh + 1 .. i*xmesh] $ i=1..ymesh], 1):

Этот список может быть передан plot::Density:

plot(plot::Density(L, FillColor = RGB::White,
                   FillColor2 = RGB::Black),
     Width = 80*unit::mm, Height = 60*unit::mm):

Изображение перевернуто, потому что файлы PGM хранят строку пиксельных данных строкой в обычном порядке чтения начиная с левого верхнего угла изображения. Стандартная программа MuPAD^® plot::Density, однако, следует за математической ориентацией осей координат, т.е. первое пиксельное значение интерпретировано как левый нижний угол изображения. Мы должны переупорядочить строки в graydata перечислите через revert:

plot(plot::Density(revert(L), FillColor = RGB::White,
                   FillColor2= RGB::Black),
     Width = 80*unit::mm, Height = 60*unit::mm):

Стандартные программы import::readbitmap и plot::Raster обеспечьте альтернативный способ импортировать и отобразить растровое изображение. Смотрите страницу справки графика:: Растр для примеров. Это, однако, берет больше памяти, потому что растровые данные импортированы как RGB значения цвета, тогда как только значения плотности (серые данные) необходимы для plot::Density.

delete graydata, magicvalue, xmesh, ymesh, maxgray, i, L:

Пример 4

Множество Мандельброта является одним из самых известных фракталов. Это возникает при считании итерации z _{n + 1} = z _n ² + c, z ₀ = 0 в комплексной плоскости. Для достаточно больших значений |c | комплексного параметра c, последовательность z _n отличается к бесконечности; это сходится для достаточно маленьких значений |c |. Контур области тех значений c, которые приводят к расхождению z _n, особенно интересен: эта граница является высоко сложной и фрактальной природы.

В частности, известно, что серия z _n отличается к бесконечности, каждый раз, когда одно из выполнения итерации удовлетворяет |z_n |> 2. Этот факт используется следующей процедурой f как останавливающийся критерий. Возвращаемое значение предоставляет информацию, сколько выполняет итерации z ₀, …, z _n, который это берет, чтобы сбежать из области |z | ≤ 2 из (потенциальной) сходимости. Эти данные должны использоваться, чтобы окрасить комплексную плоскость c (т.е. (x, y) плоскостью) графиком плотности:

f := proc(x, y)
local c, z, n;
begin
   c := x + I*y:
   z := 0.0:
   for n from 0 to 100 do
       z := z^2 + c:
       if abs(z) > 2 then 
          break;
       end_if;
   end_for:
   if n < 70 then
        n mod 5;
   else n - 70;
   end_if;
end_proc:

В зависимости от вашего компьютера могут занять время следующие расчеты. На очень быстрой машине можно увеличить следующие значения xmesh, ymesh. Это израсходует более вычислительное время, но приведет к лучшим графическим результатам:

xmesh :=  100: ymesh :=  100:

Следующая область в x-y плоскость должна быть рассмотрена:

xmin[1] := -2.0: xmax[1] := 0.5:
ymin[1] := -1.2: ymax[1] := 1.2:

Область xmin ₁ ≤ x ≤ xmax ₁, ymin ₁ ≤ y ≤ ymax ₁ разделен на xmesh ×ymesh прямоугольники. Каждый прямоугольник окрашен графиком плотности согласно “временам Escape”, вычисленным процедурой f. Эта процедура может быть передана непосредственно plot::Density:

p1 := plot::Density(f, x = xmin[1].. xmax[1],
                    y = ymin[1] .. ymax[1],
                    Mesh = [xmesh, ymesh],
                    FillColor = RGB::Black, 
                    FillColor2 = RGB::Red):

Кроме того, прямоугольник производится, который указывает на область, которая должна быть увеличена в следующем:

xmin[2] := -0.24: xmax[2] := -0.01:
ymin[2] :=  0.63: ymax[2] :=  0.92:
r1 := plot::Rectangle(xmin[2] .. xmax[2], ymin[2] .. ymax[2],
                      LineColor = RGB::White):

plot(p1, r1):

Значения плотности взрыва не вычисляются непосредственно plot::Density. Они вычисляются отдельно и хранятся в массиве A:

dx := (xmax[2] - xmin[2])/xmesh:
dy := (ymax[2] - ymin[2])/ymesh:
A := array(1..ymesh, 1..xmesh, 
           [[f(xmin[2]+ (j - 1/2)*dx, ymin[2] + (i - 1/2)*dy) 
             $ j = 1..xmesh] $ i = 1..ymesh]):
p2 := plot::Density(A, x = xmin[2] .. xmax[2], y = ymin[2] .. ymax[2],
                    FillColor = RGB::Black, FillColor2 = RGB::Red):

Кроме того, дальнейший прямоугольник производится, чтобы указать на необходимую область, которая будет аварийно завершена lateron:

xmin[3] := -0.045: xmax[3] := -0.015:
ymin[3] :=  0.773: ymax[3] :=  0.815:
r2 := plot::Rectangle(xmin[3] .. xmax[3], ymin[3] .. ymax[3],
                      LineColor = RGB::White):

plot(p2, r2):

Значения плотности следующего взрыва снова вычисляются отдельно и хранятся во вложенном списке L:

dx := (xmax[3] - xmin[3])/xmesh:
dy := (ymax[3] - ymin[3])/ymesh:
L := [[f(xmin[3] + (j - 1/2)*dx, ymin[3] + (i - 1/2)*dy) 
      $ j= 1..xmesh] $ i = 1..ymesh]:
p3 := plot::Density(L, x = xmin[3] .. xmax[3], y = ymin[3] .. ymax[3],
                    FillColor = RGB::Black, FillColor2 = RGB::Red):

plot(p3):

Объекты плотности состоят в том, чтобы быть помещены в одну графику. Это состоит из Множества Мандельброта p1 как вычислено выше и модификаций плотности строит p2 и p3. Переопределение атрибутов XRangeYRange , мы перемещаем p2, p3 к местам в x-y плоскость, где они не перекрываются p1. Обратите внимание на то, что это не изменяет графическое содержимое p2, p3, потому что это дано по условию A и L, соответственно, которые остаются неизменными. (Если области значений были изменены в p1, другой plot вызов p1 вызвал бы процедуру f в различных точках плоскости, приводящей к различной графике.)

p2::XRange :=  0.60 .. 1.60: p2::YRange :=  0.05 ..  1.15:
p3::XRange :=  0.60 .. 1.60: p3::YRange := -1.15 .. -0.05:

Множество Мандельброта и эти два взрыва помещаются в одну сцену. Кроме того, некоторые стрелы добавляются, чтобы указать на источник взрывов. Обратите внимание на то, что довольно важно здесь, чтобы стрелы были переданы plot команда после графиков плотности. В противном случае они были бы скрыты графиками плотности: графические объекты нарисованы в упорядоченном расположении, в котором они передаются plot:

plot(p1, p2, p3,
     plot::Arrow2d([(xmin[2] + xmax[2])/2, 
                    (ymin[2] + ymax[2])/2],
                   [(p2::XMin + p2::XMax)/2, 
                    (p2::YMin + p2::YMax)/2],
                   LineColor = RGB::Blue),
     plot::Arrow2d([1.50, 0.65],
                   [(p3::XMin + p3::XMax)/2, 
                    (p3::YMin + p3::YMax)/2],
                   LineColor = RGB::Blue)
    ):

delete f, xmesh, ymesh, xmin, xmax, ymin, ymax, 
       dx, dy, p1, p2, p3, r1, r2, A, L: