Атрибуты

Пример 1

Если дали один plot::Function2d объект, plot::Hatch штрихует область между кривой и осью X:

f := plot::Function2d(sin(x), x = -PI..PI):
plot(plot::Hatch(f), f)

Обратите внимание на то, что plot::Hatch требует объекта типа plot::Function2d, не только выражение function:

plot::Hatch(sin(x))

Error: Missing argument of type 'plot::Function2d' or 'plot::Curve2d'. [plot::Hatch::new]

plot::Hatch может попроситься заштриховать область между функциональным графиком и некоторым постоянным значением (т.е. некоторой линией, параллельной оси X):

plot(plot::Hatch(f, 1), f)

Для функций с полюсами, сохраняя VerticalAsymptotesVisible установите на TRUE настоятельно рекомендован:

f := plot::Function2d(1/(x - 1)):
h := plot::Hatch(f):
plot(f, h)

delete f, h:

Пример 2

Путем передачи двух функций plot::Hatch, мы просим штриховку области между двумя:

f := plot::Function2d(sin(x), x = -4 .. 4,  Color = RGB::Blue):
g := plot::Function2d(cos(2*x), x = -4 .. 4, Color=RGB::Black):
h := plot::Hatch(f, g):
plot(f, g, h)

delete f, g, h:

Пример 3

plot::Hatch может также заштриховать внутреннюю часть plot::Curve2d объект:

circle := plot::Curve2d([sin(t), cos(t)], t=0..2*PI):
plot(circle, plot::Hatch(circle))

Если кривая не закрывается, plot::Hatch расценивает первую и последнюю точку, которая будет соединена:

circle::UMax := 3*PI/2:
plot(circle, plot::Hatch(circle))

delete circle:

Пример 4

По умолчанию, plot::Hatch расширяет максимально далеко налево и право, не оставляя общую область определения всех заданных функций:

f := plot::Function2d(sin(x), x = 0 .. 5):
g := plot::Function2d(-cos(x), x = -1 .. 4):
h := plot::Hatch(f, g):
plot(f, g, h)

Можно ограничить эту область значений путем предоставления явной области значений x значений:

h := plot::Hatch(f, g, 1 .. 3):
plot(f, g, h)

Однако не возможно расширить область значений вне общей области определения обеих функций:

h := plot::Hatch(f, g, -1 .. 3):
plot(f, g, h)

Ограничение области значений x также работает на штриховку объектов кривой:

c := plot::Curve2d([sin(5*x), cos(7*x)], x = 0 .. 2*PI):
h := plot::Hatch(c, 0 .. 1):
plot(c, h)

Обратите внимание на то, что plot::Hatch реагирует на гладкость кривой. Это - одна из причин, почему необходимо обеспечить объекты вместо выражений для функций или кривых:

c::AdaptiveMesh := 2:
plot(c, h)

delete f, g, h, c:

Пример 5

Один из самых полезных атрибутов plot::Hatch FillPattern, который может принять одно из значений DiagonalLines (значение по умолчанию), FDiagonalLines, HorizontalLines, VerticalLines, CrossedLines, XCrossedLines, или Solid:

f := plot::Function2d(sin(x)):
h := plot::Hatch(f, FillPattern = VerticalLines):
plot(f, h)

Другим атрибутом, который часто будет полезен, является FillColor, изменить цвет штриховки. Мы устанавливаем значение прямо в нашем существующем объекте штриховки:

h::FillPattern := CrossedLines:
h::FillColor := RGB::Blue:
plot(f, h)

delete f, h:

Пример 6

Функция (функции) или кривая, базовая линия и ограничение области значений x могут быть анимированы:

f := plot::Function2d(sin(x + a), x = -PI..PI, a = 0..2*PI):
g := plot::Function2d(cos(x - a), x = -PI..PI, a = 0..4*PI):
plot(f, g, plot::Hatch(f, g, x0 .. x0+1, x0 = -PI..3))

f := plot::Function2d(sin(a*x), x=-PI..PI, a=0.2..3):
plot(f, plot::Hatch(f))

delete f, g:

Пример 7

“Штриховка” может также быть заливкой сплошной области:

plot(plot::Hatch(
  plot::Curve2d([abs(r)*sin(r), abs(r)*cos(r)], r = -PI..PI),
  FillPattern = Solid, FillColor = RGB::Red, Axes = None))