Взаимодействия среды

simplify реагирует на свойства идентификаторов.

Пример 1

Используйте simplify функция, чтобы упростить следующие алгебраические выражения:

simplify(exp(x)-exp(x/2)^2)

f := ln(x) + ln(3) - ln(3*x) + (exp(x) - 1)/(exp(x/2) + 1):
simplify(f)

Пример 2

Чтобы упростить Булевы выражения, используйте logic цель:

simplify((a and b) or (a and (not b)), logic)

Пример 3

В качестве альтернативы, чтобы упростить Булевы выражения, используйте condition цель. С condition цель, simplify использует свойства и предположения, заданные для условий Булевых выражений. С logic цель, simplify игнорирует те свойства и предположения:

simplify(x > x, condition), simplify(x > x, logic)

Пример 4

Опция IgnoreAnalyticConstraints позволяет вам получать более простые результаты с помощью набора чисто алгебраических упрощений:

simplify(ln(x^2 + 2*x + 1) - ln(x + 1))

simplify(ln(x^2 + 2*x + 1) - ln(x + 1), IgnoreAnalyticConstraints)

Если вы будете использовать эту опцию, simplifier не гарантирует равенства начального выражения и результата для всех символьных параметров.

Пример 5

Чтобы изменить количество шагов упрощения, используйте Steps опция:

f := ((exp(-x*I)*I)/2 - (exp(x*I)*I)/2)/(exp(-x*I)/2 + exp(x*I)/2):
simplify(f);
simplify(f, Steps = 10);
simplify(f, Steps = 50)

Пример 6

Ваши пользовательские функции могут иметь атрибуты упрощения. Например, предположите, что вы знаете, что f является аддитивной функцией, но вы не знаете больше о f. Поэтому вы не можете вычислить значение функции ни в какой точке кроме нуля, но можно использовать аддитивность:

f := funcenv( x -> if iszero(x) then 0 else procname(x) end):
f::simplify := proc(F)
                 local argument;
                 begin
                   argument := op(F,1);
                   if type(argument) = "_plus" then
                     map(argument, f)
                   else
                     F
                   end
                 end:

f(x + 3*y) - f(3*y) = simplify(f(x + 3*y) - f(3*y))

Можно совершенствовать атрибут упрощения f далее. Например, можно указать, что это должно повернуть f(3*y) в 3*f(y). Противоположное правило (переписывающий f (x) + f (y) как f (x + y)) не контекстно-свободно. Поэтому вы не можете реализовать противоположное правило в атрибуте упрощения.

Возвращаемые значения

Объект того же типа как входной объект f или L, соответственно.

Перегруженный

fL