Пример 1

В следующем мы показываем, как создать и решить скалярный ОДУ. Во-первых, мы задаем ОДУ. Мы используем лексему кавычки ' представлять производные:

eq := ode(x^2*y'(x) + 3*x*y(x) = sin(x)/x, y(x))

Мы получаем элемент доменного ode который мы можем теперь решить:

solve(eq)

delete eq:

Пример 2

Задача с начальными значениями задана как набор, состоящий из ОДУ и начальных условий:

ivp := ode({f''(t) + 4*f(t) = sin(2*t), 
            f(0) = a, f'(0) = b}, f(t))

solve(ivp)

delete ivp:

Пример 3

С некоторыми ограничениями также возможно решить системы ОДУ. Во-первых, задайте систему:

sys := {x'(t) - x(t) + y(t) = 0, y'(t) - x(t) - y(t) = 0}

Вызов solve дает к общему решению произвольными параметрами:

solution := solve(ode(sys, {x(t), y(t)}))

Чтобы проверить результат, замените им назад в систему sys. Однако для замены, необходимо переписать систему в обозначение с помощью diff функция:

eval(subs(rewrite(sys, diff), op(solution)))

delete sys, solution:

Если вы имеете систему дифференциальных уравнений в матричной форме, извлекаете компоненты матрицы к набору дифференциальных уравнений:

Y:= matrix([x(t), y(t)]):
A:= matrix([[1, 2], [-1, 6]]):
s := ode({op(diff(Y, t) - A*Y)}, {x(t), y(t)})

Теперь используйте solve функция, чтобы решить систему:

solve(s)

Пример 4

В этом примере мы указываем на различные форматы возврата odeрешите средство. Во-первых, мы решаем ОДУ с начальным условием. Решение включает символьный интеграл:

solve(ode({y'(x) + x*y(x) = cos(x), y(0) = 3}, y(x)))

Для следующего уравнения мы получаем неявное решение:

solve(ode((x*y'(x) - y(x))^4*exp(x*y'(x) - y(x)) 
          - ln(x*y'(x) - y(x)), y(x)))

Это - алгебраическое уравнение для y. Его решение задает y как функция x и произвольный параметр C сопровождаемый номером, автоматически сгенерированным MuPAD^® (постоянный из интегрирования). Однако алгебраическое уравнение не имеет решения в закрытой форме.

delete sys, solution:

Пример 5

Это может произойти, что MuPAD не может решить данное уравнение. В таком случае, символьном solve команда возвращена:

solve(ode(x*diff(y(x),x)-y(x)*(x*ln(x^3/y(x))+2), y(x)))

Пример 6

Решатель ОДУ MuPAD содержит алгебраические алгоритмы для вычисления Liouvillian и non-Liouvillian решений линейных обыкновенных дифференциальных уравнений. Эти алгоритмы основаны на дифференциале теория Галуа и на дополнительных методах для нахождения решений линейных обыкновенных дифференциальных уравнений, данных в терминах специальных функций. Для примера известного Ковэкика

решение может быть найдено как:

solve(ode(y''(x) + (3/(16*x^2) + 2/(9*(x - 1)^2)
                    - 3/(16*x*(x - 1)))*y(x), y(x)))

MuPAD может найти Liouvillian и non-Liouvillian решения для уравнений высшего порядка также. Однако в случае решений Liouvillian, нет никакой гарантии, что все они найдены.

MuPAD также находит non-Liouvillian решения в терминах функции Бесселя, Эйри и функций Уиттекера:

eq := y'(x) + y(x)^2 + b + a*x

solve(ode(eq, y(x)))

Мы проверяем это решение:

simplify(eval(subs(rewrite(eq, diff), y(x) = op(%))))

Пример 7

Также возможно вычислить серийные решения обыкновенного дифференциального уравнения (cf. ode::series для получения дальнейшей информации):

series(ode(y''(x) + 4*y(x) = sin(w*x), y(x)), x = 0, 8)

Возвращаемые значения

Объект типа ode.