Документация

2D функциональные графики: plotfunc2d

Мы рассматриваем 2D примеры, т.е. графики одномерных функций y = f (x). Вот один период синусоидальной функции:

plotfunc2d(sin(x), x = 0..2*PI):

Если несколько функций должны быть построены в той же графической сцене, только передайте последовательность выражений function. Все функции построены в указанном общем диапазоне:

plotfunc2d(sin(x)/x, x*cos(x), tan(x), x = -4..4):

Функции, которые не позволяют простое символьное представление по выражению, могут также быть заданы procedure это производит численное значение f (x), когда названо численным значением x из области значений графика. В следующем примере мы рассматриваем самое большое собственное значение симметричного 3×3 матрица, которая содержит параметр x. Мы строим это собственное значение как функцию x:

f := x -> max(numeric::eigenvalues(matrix([[-x, x, -x  ], 
                                           [ x, x,  x  ], 
                                           [-x, x,  x^2]]))):
plotfunc2d(f, x = -1..1):

x имени, используемый в спецификации области значений графического вывода, обеспечивает имя, которое помечает горизонтальную ось. Функции могут также быть заданы piecewise объекты:

plotfunc2d(piecewise([x < 1, 1 - x],
                     [1 < x and x < 2, 1/2],
                     [x > 2, 2 - x]),
           x = -2..3)

Обратите внимание на то, что существуют разрывы в определении функции выше: никакое значение функции не задано для x = 1 и x = 2. Это не вызывает проблемы, потому что plotfunc2d просто игнорирует все точки, которые не производят действительные численные значения. Таким образом, в следующем примере, график автоматически ограничивается областями, где функции производят действительные значения:

plotfunc2d(sqrt(8 - x^4), ln(x^3 + 2)/(x - 1), x = -2 ..2):

Когда несколько функций построены в той же сцене, они чертятся в различных цветах, которые выбраны автоматически. С Colors припишите можно задать список цветов RGB что plotfunc2d буду использовать:

plotfunc2d(x, x^2, x^3, x^4, x^5, x = 0..1,
           Colors = [RGB::Red, RGB::Orange, RGB::Yellow, 
                     RGB::BlueLight, RGB::Blue]):

Анимированные 2D графики функций создаются путем передачи выражений function в зависимости от переменной (x, скажите) и параметр анимации (a, скажите), и указание диапазона и для x и для a:

plotfunc2d(cos(a*x), x = 0..2*PI, a = 1..2):

Если график создается, первая система координат изображения появляется как статический график. После нажатия на изображение графический инструмент начинает проигрывать анимацию. Существуют обычные средства управления, чтобы остановиться, запуститься, и ускоренная перемотка вперед/перемотка анимация.

Количество по умолчанию систем координат анимации равняется 50. Если различное значение желаемо, только передайте атрибут Frames = n, где n является количеством систем координат, которые должны быть созданы:

plotfunc2d(sin(a*x), sin(x - a), x = 0..PI, a = 0..4*PI, 
           Colors = [RGB::Blue, RGB::Red], Frames = 200):

Кроме спецификации цветов или Frames номер, существует большое количество дальнейших атрибутов, которые могут быть переданы plotfunc2d. Каждый атрибут передается как уравнение AttributeName = AttributeValue к plotfunc2d. Здесь, мы только представляем некоторые выбранные атрибуты. Смотрите раздел по атрибутам для plotfunc для дальнейших таблиц с большим количеством атрибутов.

Следующий пример графика показывает известную функцию, которая колеблется дико около источника:

plotfunc2d(sin(1/x), x = -0.5..0.5):

Безусловно, значение по умолчанию 121 точки выборки используется plotfunc2d не достаточен, чтобы создать достаточно разрешенный график. Мы увеличиваем число числовых точек mesh через Mesh атрибут. Кроме того, мы увеличиваем глубину разрешения адаптивного механизма графического вывода от его значения по умолчанию AdaptiveMesh = 2 к AdaptiveMesh = 4:

plotfunc2d(sin(1/x), x = -0.5..0.5, Mesh = 500,
           AdaptiveMesh = 4):

Следующий вызов задает заголовок через Header = "The function sin(x^2)". Расстояние между помеченными метками деления установлено в 0,5 вдоль  оси x и в 0,2 вдоль  оси y через XTicksDistance = 0.5 и YTicksDistance = 0.2, соответственно. Четыре дополнительных непомеченных метки деления между каждой парой помеченных меток деления установлены в направлении x через XTicksBetween = 4. Одну дополнительную непомеченную метку деления между каждой парой помеченных меток деления в направлении y требуют через YTicksBetween = 1. Линии сетки, присоединенные к меткам деления, “включаются” GridVisible = TRUE и SubgridVisible = TRUE:

plotfunc2d(sin(x^2), x = 0..7,
           Header = "The function sin(x^2)",
           XTicksDistance = 0.5, YTicksDistance = 0.2,
           XTicksBetween = 4, YTicksBetween = 1,
           GridVisible = TRUE, SubgridVisible = TRUE):

Когда сингулярность найдена в функции, автоматическое усечение называется, пытаясь ограничить вертикальную область значений просмотра в некотором роде, чтобы получить “довольно” масштабируемое изображение. Это - эвристический подход, для которого иногда нужна адаптация помощи “вручную”. В следующем примере, автоматически выбранной области значений между y ≈ - 1 и y ≈ 440 в вертикальном направлении подходит, чтобы представлять 6-й полюс порядка в x = 1, но это не обеспечивает хорошее разрешение полюса первого порядка в x = - 1:

plotfunc2d(1/(x + 1)/(x - 1)^6, x = -2..2):

Нет никакой хорошей области значений просмотра, которая достаточна для обоих полюсов, потому что они имеют различный порядок. Однако некоторый компромисс может быть найден. Мы заменяем автоматическую область значений просмотра, предложенную plotfunc2d и запросите определенную область значений просмотра в вертикальном направлении через ViewingBoxYRange:

plotfunc2d(1/(x + 1)/(x - 1)^6, x = -2..2, 
           ViewingBoxYRange = -10..10):

Значения следующей функции имеют нижнюю границу, но никакую верхнюю границу. Мы используем атрибут ViewingBoxYRange = Automatic..10 позволять plotfunc2d найдите нижнюю границу для поля просмотра отдельно при запросе определенного значения 10 для верхней границы:

plotfunc2d(exp(x)*sin(PI*x) + 1/(x + 1)^2/(x - 1)^4, x = -2..2, 
           ViewingBoxYRange = Automatic..10):

3D функциональные графики: plotfunc3d

Мы рассматриваем 3D примеры, т.е. графики двумерных функций z = f (x, y). Вот график функционального sin (x ² + y ²):

plotfunc3d(sin(x^2 + y^2), x = -2..2, y = -2..2):

Если несколько функций должны быть построены в той же графической сцене, только передайте последовательность выражений function; все функции построены в указанном общем диапазоне:

plotfunc3d((x^2 + y^2)/4, sin(x - y)/(x - y),
                       x = -2..2, y = -2..2):

Функции, которые не позволяют простое символьное представление по выражению, могут также быть заданы procedure это производит численное значение f (x, y), когда названо численными значениями x, y из области значений графика. В следующем примере мы рассматриваем самое большое собственное значение симметричного 3×3 матрица, которая содержит два параметра x, y. Мы строим это собственное значение как функцию x и y:

f := (x, y) -> max(numeric::eigenvalues(
                   matrix([[-y, x, -x],
                             [x, y, x],
                          [-x, x, y^2]]))):
plotfunc3d(f, x = -1..1, y = -1..1):

Имена x, y, используемый в спецификации области значений графического вывода, обеспечивают метки соответствующих осей. Функции могут также быть заданы piecewise объекты:

plotfunc3d(piecewise([x < y, y - x], [x > y, (y - x)^2]),
                                     x = 0..1, y = 0..1)

Обратите внимание на то, что существуют разрывы в определении функции выше: никакое значение функции не задано для x = y. Это не вызывает проблемы, потому что plotfunc3d просто игнорирует точки, которые не производят действительные численные значения, если это находит подходящие значения в окружении. Таким образом упускающая суть не обнаруживается в графике, если эти точки изолируются или ограничиваются некоторой 1-мерной кривой в x-y плоскость. Если функция не действительна оцененный в областях ненулевой меры, получившийся график содержит отверстия. Следующая функция действительна оцененный только в диске x ² + y ² ≤ 1:

plotfunc3d(sqrt(1 - x^2 - y^2), x = 0..1, y = 0..1):

Когда несколько функций построены в той же сцене, они чертятся в различных цветах, которые выбраны автоматически. С Colors припишите можно задать список цветов RGB что plotfunc3d буду использовать:

plotfunc3d(2 + x^2 + y^2, 1 + x^4 + y^4, x^6 + y^6,
           x = -1..1, y = -1..1,
           Colors = [RGB::Red, RGB::Green, RGB::Blue]):

Анимированные 3D графики функций создаются путем передачи выражений function в зависимости от двух переменных (x, y, скажите) и параметр анимации (a, скажите), и указание диапазона для x, y и a:

plotfunc3d(x^a + y^a, x = 0..2, y = 0..2, a = 1..2):

Если график создается, первая система координат изображения появляется как статический график. После двойного клика на изображении, запусках анимации. Обычные средства управления для остановки, идя в некоторый другой момент времени и т.д. доступны.

Количество по умолчанию систем координат анимации равняется 50. Если различное значение желаемо, только передайте атрибут Frames = n, где n является количеством систем координат, которые должны быть созданы:

plotfunc3d(sin(a)*sin(x) + cos(a)*cos(y),
                x = 0..2*PI, y = 0..2*PI,
                a = 0..2*PI, Frames = 32):

Кроме спецификации цветов или Frames номер, существует большое количество дальнейших атрибутов, которые могут быть переданы plotfunc3d. Каждый атрибут передается как уравнение AttributeName = AttributeValue к plotfunc3d. Здесь, мы только представляем некоторые выбранные атрибуты. Разделите Атрибуты для plotfunc2d, и plotfunc3d предоставляет дальнейшим таблицам больше атрибутов.

В следующем примере mesh по умолчанию 25 ×25 точек выборки используется plotfunc3d не достаточен, чтобы создать достаточно разрешенный график:

plotfunc3d(sin(x^2 + y^2), x = -3..3, y = -3..3):

Мы увеличиваем число числовых точек mesh через Submesh атрибут:

plotfunc3d(sin(x^2 + y^2), x = -3..3, y = -3..3, Submesh = [3, 3])

Следующий вызов задает заголовок через Header = "The function sin(x - y^2)". Линии сетки, присоединенные к меткам деления, “включаются” GridVisible = TRUE и SubgridVisible = TRUE:

plotfunc3d(sin(x - y^2), x = -2*PI..2*PI, y = -2..2,
           Header = "The function sin(x - y^2)",
           GridVisible = TRUE, SubgridVisible = TRUE):

Когда сингулярность найдена в функции, автоматическое усечение называется, пытаясь ограничить вертикальную область значений просмотра в некотором роде, чтобы получить “довольно” масштабируемое изображение. Это - эвристический подход, для которого иногда нужна адаптация помощи “вручную”. В следующем примере, автоматически выбранной области значений между z ≈ 0 и z ≈ 0.8 в вертикальном направлении подходит, чтобы представлять полюс в x = 1, y = 1, но это не обеспечивает хорошее разрешение полюса в x = - 1, y = 1:

plotfunc3d(1/((x + 1)^2 + (y - 1)^2)/((x - 1)^2 + (y - 1)^2)^5,
                        x = -2..3, y = -2..3, Submesh = [3, 3]):

Нет никакой хорошей области значений просмотра, которая достаточна для обоих полюсов, потому что они имеют различный порядок. Мы заменяем автоматическую область значений просмотра, предложенную plotfunc3d и запросите определенную область значений просмотра в вертикальном направлении через ViewingBoxZRange:

plotfunc3d(1/((x + 1)^2 + (y - 1)^2)/((x - 1)^2 + (y - 1)^2)^5,
                                          x = -2..3, y = -2..3,
                   Submesh = [3, 3], ViewingBoxZRange = 0..0.1):

Значения следующей функции имеют нижнюю границу, но никакую верхнюю границу. Мы используем атрибут ViewingBoxZRange = Automatic..20 позволять plotfunc2d найдите нижнюю границу для поля просмотра отдельно при запросе определенного значения 20 для верхней границы:

plotfunc3d(1/x^2/y^2 + exp(-x)*sin(PI*y),
                    x = -2..2, y = -2..2,
        ViewingBoxZRange = Automatic..20):

Атрибуты для plotfunc2d и plotfunc3d

Функциональные плоттеры plotfunc2d и plotfunc3d примите большое количество атрибутов (опции). В этом разделе мы даем обзор по самым важным атрибутам. Существует страница справки для каждого атрибута, который обеспечивает более подробную информацию и примеры.

Атрибуты передаются как уравнения AttributeName = AttributeValue к plotfunc2d и plotfunc3d. Несколько атрибутов могут быть переданы одновременно как последовательность таких уравнений.

Атрибуты могут быть изменены в интерактивном режиме в инспекторе свойств. Нажмите на график заставить подокна появиться для “обозревателя объектов” и “инспектора свойств” (см. раздел Viewer, Браузер и Инспектора: Интерактивная Манипуляция). Функции построены по plotfunc2d и plotfunc3d появитесь как объекты графика типа plot::Function2d и plot::Function3d, соответственно. Они встраиваются в систему координат в графической сцене. Сцена встраивается в область просмотра, названную 'Холстом'. В средстве просмотра различные атрибуты графика сопоставлены с различными объектами этой графической иерархии. Как правило, параметры размещения и заголовки установлены в холсте, пока оси, линии сетки, просматривающие поля и т.д. сопоставлены с системой координат. Некоторые атрибуты, такие как цвета, ширина линии, числовой размер mesh и т.д. принадлежит функциональным графикам и может быть установлен отдельно для каждой функции, построенной по plotfunc2d/plotfunc3d.

Последняя запись в следующих таблицах обеспечивает местоположение атрибута в графической иерархии обозревателя объектов. Например, для изменения цвета фона изображения, выберите сцену путем двойного щелчка по ‘Scene2d’/‘Scene3d’ запись в обозревателе объектов. Теперь инспектор свойств предоставляет дереву атрибутов с узлами 'Аннотация', 'Размещение' и 'Стиль'. Открывая поддерево 'Стиля', каждый находит запись для BackgroundColor который позволяет изменять цвет фона в интерактивном режиме.

Вот таблица самых важных атрибутов для установки размещения и фона изображения:

Полный заголовок может быть установлен как нижний колонтитул и/или заголовок. Вот таблица атрибутов, определяющих нижний колонтитул и/или заголовок изображения:

Кроме нижних колонтитулов и/или заголовков сцен и холста, существуют заголовки, сопоставленные с функциями. В отличие от нижнего колонтитула и заголовка, функциональные заголовки могут быть помещены куда угодно в системе координат через атрибут TitlePosition. Как правило, заголовки сопоставлены с отдельными объектами, а не с целыми сценами. Таким образом, при использовании plotfunc2d или plotfunc3d, атрибут заголовка будет обычно только использоваться, когда одна функция будет отображена. Однако несколько заголовков с отдельными положениями могут быть установлены в интерактивном режиме в инспекторе свойств для каждой из функций:

Если несколько функций чертятся одновременно в одном изображении, полезно отобразить легенду, указывающую, какой цвет используется в который функция. Смотрите раздел Legends для получения дальнейшей информации по легендам. Вот таблица самых важных атрибутов, определяющих форму легенды. Атрибуты LegendEntry, LegendText, и LegendVisible = TRUE установлены автоматически plotfunc2d/plotfunc3d если больше чем одна функция построена. Инспектор свойств (Средство просмотра, Браузер и Инспектор: Интерактивная Манипуляция), позволяет сбрасывать запись легенды для каждой функции:

Когда сингулярные функции построены, часто полезно запросить определенную область значений просмотра. Вот таблица самых важных атрибутов для установки областей значений просмотра. В браузере интерактивного объекта вы найдете их под CoordinateSystem2d (CS2d) и CoordinateSystem3d (CS3d), соответственно:

В отличие от стандартных программ plot библиотека, plotfunc2d и plotfunc3d также примите атрибуты YMinymax YRange и ZMinzmax ZRange , соответственно, как ярлыки для несколько неуклюжих названий атрибута ViewingBoxYMin и т.д. Например,

plotfunc2d(f(x), x = xmin..xmax, YRange = ymin..ymax)

эквивалентно

plotfunc2d(f(x), x = xmin..xmax,
           ViewingBoxYRange = ymin..ymax)

и

plotfunc3d(f(x, y), x = xmin..xmax, y = ymin..ymax,
           ZRange = zmin..zmax)

эквивалентно

plotfunc3d(f(x, y), x = xmin..xmax, y = ymin..ymax,
           ViewingBoxZRange = zmin..zmax)

Вот таблица самых важных атрибутов для расположения осей координат. В браузере интерактивного объекта вы найдете их под CoordinateSystem2d (CS2d) и CoordinateSystem3d (CS3d), соответственно:

Вот таблица самых важных атрибутов для установки отметок деления и меток в виде галочки вдоль осей. В браузере интерактивного объекта вы найдете их под CoordinateSystem2d (CS2d) и CoordinateSystem3d (CS3d), соответственно:

Линии координатной сетки могут быть проведены в фоновом режиме графической сцены (соответствующий управлениям выровненной бумаги). Они присоединены к отметкам деления вдоль осей. Существуют линии сетки, присоединенные к “главным” помеченным отметкам деления, которые упоминаются как “Grid.” Существуют также линии сетки, сопоставленные с “незначительным” непомеченным набором отметок деления быть атрибутом TicksBetween. Эти “незначительные” линии сетки упоминаются как “Subgrid.” Два вида линий сетки могут быть установлены независимо. В браузере интерактивного объекта вы найдете следующие атрибуты под CoordinateSystem2d (CS2d) и CoordinateSystem3d (CS3d), соответственно:

Анимации требуют того графического вывода области значений x = xmin..xmax (и y = ymin..ymax) полностью заданы в plotfunc2d (или plotfunc3d, соответственно). Анимации инициированы путем передачи дополнительной области значений, такой как a = amin..amax к plotfunc2d/plotfunc3d. Параметр анимации a может подняться в выражении функций, которые должны быть построены, а также в различных других местах, таких как координаты заголовков и т.д. Смотрите раздел Graphics и Animations для деталей.

Функции построены как многоугольники, состоящие из сегментов прямой линии между точками “числовой mesh”. Число точек в этой числовой mesh установлено различными атрибутами “mesh”:

В 2D изображениях, сгенерированных plotfunc2d, сингулярность функции обозначается вертикальными линиями (“вертикальные асимптоты”), если DiscontinuitySearch = FALSE установлен. Вот таблица с атрибутами для установки стиля вертикальных асимптот:

Цвета функций построены по plotfunc2d выбраны автоматически. Инспектор свойств (см. раздел Viewer, Браузер и Инспектора: Интерактивная Манипуляция), позволяет изменять эти атрибуты:

Установка LinesVisible = FALSE и PointsVisible = TRUE, функции построены по plotfunc2d не будет отображен как многоугольники, но как последовательности точек. Вот таблица атрибутов, чтобы установить стиль презентации точек:

Цвета и поверхностные стили функций построены по plotfunc3d выбраны автоматически. Инспектор свойств (см. раздел Viewer, Браузер и Инспектора: Интерактивная Манипуляция), позволяет изменению эти атрибуты:

Помимо обычных линейных графиков, логарифмические графики также возможны путем выбора соответствующего CoordinateType.

С Scaling = Constrained, модуль окружает координаты модели (квадрат в 2D, куб в 3D) отображен как модульное поле. С Scaling = Unconstrained, средство отображения применяет различное преобразование масштабирования в координатных направлениях, чтобы получить оптимальный припадок изображения в окне экрана. Это, однако, может исказить круг к эллипсу. С Scaling = Constrained 2D круг появляется на экране как круг, 3D сфера появляется как сфера.

2D функции предварительно обрабатываются полусимвольным поиском разрывов, чтобы улучшить графическое представление около сингулярности и избежать графических артефактов. Если непрерывные функции построены, можно получить, некоторые убыстряются путем выключения этого поиска с DiscontinuitySearch = FALSE.

Когда очень трудоемкие графики состоят в том, чтобы быть созданы, может быть полезно создать графики в “пакетном режиме”. С атрибутом OutputFile = filename, вывод графических данных не представляется на экран. Внешний файл с указанным именем, содержащим графические данные, создается вместо этого. Это может содержать данные XML, которые могут быть просмотрены позже путем открытия файла с инструментом 'VCam' графики MuPAD^®. В качестве альтернативы растровые файлы в различных стандартных растровых форматах, таких как bmp, jpg и т.д. могут быть созданы, который может быть просмотрен другими стандартными инструментами. Смотрите раздел Batch Mode для получения дальнейшей информации.